[UOS] 도화선 만들기

도화선을 만드는 스크립입니다.


1. 준 비 물
판자, 유황, 초석, 실뭉치, 오븐, 수조, 물통(오토리필), 철괴
요리술 GM, 연금술 GM

요리술이 다른 캐릭터에 있는 경우
목탄을 미리 만들어서 재료 상자에 넣으세요

 

연금술 목걸이+연금술 부적 = 합 30% 이상인 경우 실패 없이 제작 가능
(성공률 도화선 90%, 검정화약 70%)


2. 사용 방법
재료 상자를 연 상태에서 해당 스크립을 실행하고,
재료 상자를 선택합니다.


3. 주 의 점
GM과 미팅시 감옥에 가실 수 있습니다.

---

드래그, 복사하면 됩니다.

headmsg '재료가 들어있는 시큐어를 선택해주세요'
promptalias 'bag'
while not dead
  if counttype 0x1bf2 0 'backpack' < 50
    movetype 0x1bf2 'bag' 'backpack' (0 0 0) 0 100
    pause 1200
  elseif counttype! 0x1eb9 0 'backpack' < 2
    usetype '0x1eb9'
    waitforgump 0x1cc 2400
    replygump 0x1cc 11
    waitforgump 0x1cc 2400
    replygump 0x1cc 0
    pause 1200
  elseif counttype! 0xe9b 0 'backpack' < 2
    usetype '0x1eb9'
    waitforgump 0x1cc 2400
    replygump 0x1cc 9
    waitforgump 0x1cc 2400
    replygump 0x1cc 0
    pause 1200
  elseif counttype! 0x97f 0 'backpack' < 2
    usetype '0x1eb9'
    waitforgump 0x1cc 2400
    replygump 0x1cc 26
    waitforgump 0x1cc 2400
    replygump 0x1cc 0
    pause 1200
  elseif @findtype '0x1420' '1164' 'backpack'
    headmsg '도화선 보관'
    moveitem 'found' 'bag'
    pause 1200
  elseif @findtype '0x423a' '1109' 'backpack'
    if not @findtype '0x423a' '1102' 'backpack'
      if not @findtype '0x1bd7' '0' 'backpack'
        movetype 0x1bd7 'bag' 'backpack' (0 0 0) 0 1
        pause 1200
      endif
      headmsg '잿물 만들기'
      usetype '0xe9b'
      waitforgump 0x1cc 2400
      replygump 0x1cc 160
      waitforgump 0x1cc 2400
      replygump 0x1cc 0
      pause 1200
    elseif not @findtype '0xe1d' '0' 'backpack'
      movetype 0xe1d 'bag' 'backpack' (0 0 0) 0 1
      pause 1200
    else
      headmsg '도화선 만들기'
      usetype '0xe9b'
      waitforgump 0x1cc 2400
      replygump 0x1cc 163
      waitforgump 0x1cc 2400
      replygump 0x1cc 0
      pause 1200
    endif
  elseif not @findtype '0x423a' '1190' 'backpack'
    if @findtype '0x423a' '1190' 'bag'
      moveitem 'found' 'backpack' (0 0 0) 1
      pause 1200
    else
      if not @findtype '0x1bd7' '0' 'backpack'
        movetype 0x1bd7 'bag' 'backpack' (0 0 0) 0 1
        pause 1200
      endif
      headmsg '목탄 만들기'
      usetype '0x97f'
      waitforgump 0x1cc 2400
      replygump 0x1cc 74
      waitforgump 0x1cc 2400
      replygump 0x1cc 0
      pause 1200
    endif
  elseif @findtype '0x423a' '1190' 'backpack'
    if not counttype '0x423a' '1150' 'backpack' == 6
      if @findtype '0x423a' '1150' 'backpack'
        moveitem 'found' 'bag'
        pause 1200
      endif
      movetype '0x423a' 'bag' 'backpack' (0 0 0) '1150' 6
      pause 1200
    endif
    if not counttype '0xf8c' '0' 'backpack' == 1
      if @findtype '0xf8c' '0' 'backpack'
        moveitem 'found' 'bag'
        pause 1200
      endif
      movetype '0xf8c' 'bag' 'backpack' (0 0 0) '0' 1
      pause 1200
    endif
    headmsg '흑색화약 만들기'
    usetype '0xe9b'
    waitforgump 0x1cc 2400
    replygump 0x1cc 161
    waitforgump 0x1cc 2400
    replygump 0x1cc 0
    pause 1200
  endif
  pause 100
endwhile