[UOS] 전사 공격 스크립(캐릭 육성시)

부넼팔 전사를 키울때

 

유용한 스크립입니다.

 

부시도 120까지 사용하셔도 됩니다.

 

 

전송가방이 있으시면

 

55000골드가  되면 자동으로 은행으로 전송합니다.

 

*전송가방과 같은 모양의 주머니가 백팩에 있으면 사용 불가

warmode 'on'
// -----------------------------------
if not timerexists 'OnSlaughtTimer'
  createtimer 'OnSlaughtTimer'
endif
// -----------------------------------
@getenemy 'murderer' 'criminal' 'gray' 'enemy' 'closest'
if @inrange 'enemy' '15'
  if graphic 'enemy' != '0xa7' or graphic 'enemy' != ''
    // Virtue
    if hits 'enemy' == maxhits 'enemy'
      headmsg '* Honor *' 34
      @virtue 'honor'
      waitfortarget 500
      target! 'enemy'
    endif
    // Attack
    autotargetenemy
    attack! 'enemy'
    // Consecrate
    if not buffexists '1082'
      headmsg '* Consecrate Weapon *' 89
      cast 'Consecrate Weapon'
      pause 600
    endif
    // Bushido Stance
    if not buffexists '1093' and hits < 100
      headmsg '* Confidence *' 34
      cast 'Confidence'
      pause 600
    elseif not buffexists '1095'
      headmsg '* Counter Attack *' 124
      cast 'Counter Attack'
      pause 600
    endif
    // OnSlaught
    if timer 'OnSlaughtTimer' > 6000
      headmsg '* Onslaught *' 34
      cast "OnslaughtSpell"
      settimer 'OnSlaughtTimer' 0
      pause 1000
      @clearusequeue
      @cancelautotarget
      replay
    endif
    // Use Primary
    //    if mana > 20
    //      headmsg '* Primary Attack *' 44
    //      @setability 'primary' 'on'
    //      pause 1000
    // Lightning Strike
    if not buffexists '1096'
      headmsg '* Lightning strike *' 54
      cast 'lightning strike'
      pause 1000
    else
      headmsg '* Nothing to Do *' 996
      pause 600
    endif
    @clearusequeue
    @cancelautotarget
  endif
else
  if poisoned 'self'
    headmsg '* Cleanse by Fire *' 34
    cast "Cleanse by Fire"
    waitfortarget 5000
    target! 'self'
  else
    headmsg 'no enemy' 74
    settimer 'OnSlaughtTimer' 3000
    pause 600
  endif
endif
// -----------------------------------
//
//
if gold >= 55000
  headmsg '* Move Gold *' 54
  if @findtype '0xe76' 'any' 'backpack'
    @setalias 'BagOfSending' 'found'
    if @findtype '0xeed' 'any' 'backpack'
      useobject 'BagOfSending'
      waitfortarget 500
      target 'found' 500
    endif
  endif
endif
if @inrange 'enemy' '5'
  attack! 'enemy'
  @clearusequeue
  @cancelautotarget
endif

 

 

무게로 골드 전송을 원하실때는 

아래 문구로 교체해 주세요.

 

자신의 무게에 맞게 수치를 조정하세요 ^^

if weight > 550
  usetype '0xe76'
  waitfortarget 2000
  targettype 0xeed
endif